Lineas entre Puntos AutoUpdatada

shenmue · 10 nov 2006

Mirando la ayuda de maxscript he reescrito el script

Código HTML:

      fn Lineas P1 P2 =     
	        (
			
		     ss = SplineShape Pos:P1
			 addNewSpline ss
			 addknot ss 1 #corner #line P1
			 addKnot ss 1 #corner #line P2
			 updateShape SS
			 ss
			       )

Lo que no me sale es conseguir que al mover los puntos,la lineas siga sus posiciones en el visor.He probado con el dependsOn,pero no me sale.

promineo · 10 nov 2006

........... Duplicadooo

promineo · 10 nov 2006

a mi se me ha ocurrido esto

Cita:

fn Lineas P1 P2 =
(
ss = SplineShape Pos:P1.pos
addNewSpline ss
addknot ss 1 #corner #line P1.pos
addKnot ss 1 #corner #line P2.pos
updateShape SS

addModifier ss (Skin ())
mySkin = ss.modifiers[#Skin]
max modify mode
modPanel.setCurrentObject mySkin
skinOps.addBone mySkin P1 1
skinOps.addBone mySkin P2 1

select P1
ss
)

P1 Y P2 son ahora dos nodos cualquiera, dos objetos...

HalfVector · 10 nov 2006

También puedes utilizar un controlador de tipo "Point3 script":

Código:

fn attachShapeToPoints P1 P2 = (
	ss = SplineShape Pos:P1.pos
	addNewSpline ss
	addknot ss 1 #corner #line P1.pos
	addKnot ss 1 #corner #line P2.pos
	updateShape ss

	local ctrlSource = "target.pos * (inverse owner.transform)"
	
	animateVertex ss #all
	
	local ctrlP1 = Point3_Script()
	ctrlP1.addNode "target" P1
	ctrlP1.addNode "owner" ss
	ctrlP1.script = ctrlSource
	ctrlP1.update()
	ss[4][8][2].controller = ctrlP1

	local ctrlP2 = Point3_Script()
	ctrlP2.addNode "target" P2
	ctrlP2.addNode "owner" ss
	ctrlP2.script = ctrlSource
	ctrlP2.update()
	ss[4][8][5].controller = ctrlP2

	OK
)

Ahora en lugar de pasar a la función dos posiciones, le pasas los dos helpers que sirven como puntos de referencia. La función ya se encarga de crear el script controller.

Saludos.

shenmue · 10 nov 2006

Esta muy bien promineo,pero igual tener que skinear la linea es un poco engorroso,no?Lo skinear splines lo he hecho pero para otras situacion.Molaria algo mas limpio.
Gracias por la idea

shenmue · 10 nov 2006

Ok.Gracias half.Voy a probarlo dentro de un rato..que ando algo saturado a estas horas

HalfVector · 10 nov 2006

Le he hecho unas cuantas modificaciones para que soporte un número de puntos arbitrario.

Código:

fn attachShapeToPoints points = (

	theShape = SplineShape()
	addNewSpline theShape
	for i = 1 to points.count do (
		addknot theShape 1 #corner #line points[i].pos
	)

	updateShape theShape

	local ctrlSource = "target.pos * (inverse owner.transform)"
	
	animateVertex theShape #all

	for i = 0 to (points.count - 1) do (
		local ctrl = Point3_Script()
		ctrl.addNode "target" points[i + 1]
		ctrl.addNode "owner" theShape
		ctrl.script = ctrlSource
		ctrl.update()
		theShape[4][8][i * 3 + 2].controller = ctrl
	)

	-- Comentar estas dos líneas si no se quiere congelar la spline
	theShape.showFrozenInGray = false
	freeze theShape
	
	OK
)

Por ejemplo puedes hacer que se cree una spline con todos los helpers de tipo "Point" que tengas en la escena:

Código:

attachShapeToPoints $Point*

Saludos.

PD: he hecho que la spline se congele para que la manipulación de los puntos sea más sencilla.

promineo · 10 nov 2006

que chulo half no sabia sobre el point3_Script con esto se pueden hacer un monton de cosas...

HalfVector · 10 nov 2006

Cita:

Escritos por promineo

que chulo half no sabia sobre el point3_Script con esto se pueden hacer un monton de cosas...

Sí, lo que pasa es que al principio me he rayado un poco porque al script controller le ponía:

Código:

target.pos

Y el vértice de la spline no seguía de forma correcta al "point helper". Entonces me he acordado que el controller espera la posición en object space, es decir, el espacio relativo al sistema de coordenadas definido por la matriz de transformación del shape. De ahí que al final haga:

Código:

target.pos * (inverse owner.transform)

Lo que hace eso es pasar la posición del punto al sistema de coordenadas del shape.

En fin, una pequeña explicación por si os preguntábais por qué transformaba el punto por la inversa de la matriz de transformación del shape.

Por cierto, he modificado el script del anterior mensaje para que congele la spline. Así la manipulación de los puntos de control es más sencilla.

Saludos.

shenmue · 10 nov 2006

Si esque si esque,quieras que no,half como que tiene algo de idea de script

10 nov 2006	#1
shenmue Senior Member Fecha de Ingreso: febrero-2005 Ubicación: politecnico/3D,3D/politecnico Mensajes: 1,911	Lineas entre Puntos AutoUpdatada Mirando la ayuda de maxscript he reescrito el script Código HTML: fn Lineas P1 P2 = ( ss = SplineShape Pos:P1 addNewSpline ss addknot ss 1 #corner #line P1 addKnot ss 1 #corner #line P2 updateShape SS ss ) Lo que no me sale es conseguir que al mover los puntos,la lineas siga sus posiciones en el visor.He probado con el dependsOn,pero no me sale.

10 nov 2006	#2
promineo reBorn Fecha de Ingreso: diciembre-2004 Ubicación: Tenerife Mensajes: 2,825	Re: Lineas entre Puntos AutoUpdatada ........... Duplicadooo __________________ PromineoStudios Cocoe Sin riesgos en la lucha, no hay gloria en la victoria Última edición por promineo fecha: 10 nov 2006 a las 16:15.

10 nov 2006	#5
shenmue Senior Member Fecha de Ingreso: febrero-2005 Ubicación: politecnico/3D,3D/politecnico Mensajes: 1,911	Re: Lineas entre Puntos AutoUpdatada Esta muy bien promineo,pero igual tener que skinear la linea es un poco engorroso,no?Lo skinear splines lo he hecho pero para otras situacion.Molaria algo mas limpio. Gracias por la idea

10 nov 2006	#6
shenmue Senior Member Fecha de Ingreso: febrero-2005 Ubicación: politecnico/3D,3D/politecnico Mensajes: 1,911	Re: Lineas entre Puntos AutoUpdatada Ok.Gracias half.Voy a probarlo dentro de un rato..que ando algo saturado a estas horas

10 nov 2006	#8
promineo reBorn Fecha de Ingreso: diciembre-2004 Ubicación: Tenerife Mensajes: 2,825	Re: Lineas entre Puntos AutoUpdatada que chulo half no sabia sobre el point3_Script con esto se pueden hacer un monton de cosas... __________________ PromineoStudios Cocoe Sin riesgos en la lucha, no hay gloria en la victoria

Usuarios activos actualmente viendo este tema: 1 (0 miembros y 1 visitantes)

Temas Similares
Tema	Autor	Foro	Respuestas	Último mensaje
Video Edicion Premiere	3dpoder	Adobe Premiere	6	26 jul 2008 00:41
Manual 3dsMax	3dpoder	3DStudio Max	0	13 ago 2005 08:45
Tracking automático con BOUJOU	3dpoder	3DStudio Max	1	23 abr 2005 17:15
En el Primer puesto: Entre el Cielo y la Tierra	3dpoder	Primer concurso de 3dpoder: Finalizado	1	28 jun 2003 08:08