Gracias Gracias:  1
Resultados 1 al 14 de 14

Tema: Una imagen para compartir

  1. #1
    Senior Member Avatar de Yue
    Fecha de ingreso
    May 2008
    Ubicación
    Bogotá
    Mensajes
    634

    Una imagen para compartir.

    Una imagen para compartir -6763221yue.jpg
    Un saludo.
    "No son ni estrellas ni ídolos, son solo gente común que quiere hacer historia"

  2. #2
    Expulsado
    Fecha de ingreso
    Dec 2010
    Ubicación
    En matrix
    Mensajes
    1,681

    Re: Una imagen para compartir.

    Puedes postear algún código en .bb sobre como hacer eso? He aprendido mucho leyendote en el foro y a otros también. Gracias Blitz3D.

  3. #3
    Senior Member Avatar de Yue
    Fecha de ingreso
    May 2008
    Ubicación
    Bogotá
    Mensajes
    634

    Re: Una imagen para compartir.

    Hola, en el momento no tengo el codigo, pues no tengo computadora lo tengo en una usb pues hago de vez en cuando cosas cuando vengo a una sala de Internet. (Prometo poner el codigo)

    En teoría se puede hacer de tres formas.

    - Primero: usando los comandos ReadPixel, FastPixel y otros.
    -Segundo: Creando un modelo que simula los rayos de luz de la ventana, a este modelo se le pone una textura y se le aplica alpha para transparencia.
    -Tercero : usando una lib externa, que no es más que un atropello pues desmerita lo que se puede hacer con blitz3d.

    En mi caso use la primera opción, como te comento existen comando que leen los pixles de la textura y se proyectan, no es tan complicado y prometo traer el codigo.

    Bueno un saludo. Haber si algún día me encuentro una pc.
    "No son ni estrellas ni ídolos, son solo gente común que quiere hacer historia"

  4. #4
    Expulsado
    Fecha de ingreso
    Dec 2010
    Ubicación
    En matrix
    Mensajes
    1,681

    Re: Una imagen para compartir.

    Gracias Blitz3D. Esperare con ganas que postees el código, como has echo otras veces, para poder aprender de el.
    No entiendo muy bien lo de proyectar los pixeles...bueno esperaré el código.

  5. #5
    Senior Member Avatar de Yue
    Fecha de ingreso
    May 2008
    Ubicación
    Bogotá
    Mensajes
    634

    Re: Una imagen para compartir.

    Código:
    ; Ejemplo de Rayos de Sol. By Yue Rexie
    ; Para Aprendiz.
    ; Libre uso.
    ; http://www.iris3d.tque <<<<<<<<<<<<<<
    ; Algo que he aprendido en la vida : 
    ; Es que no es necesario ir a una escuela para aprender
    ; lo que realmente nos gusta....
    ; Joder nadie me cree. Y soy como el perro que ha visto el arcoiris.
    Graphics3D 800,600,32,2
    SetBuffer BackBuffer()
    
    camera=CreateCamera()
    TranslateEntity camera,0,0,-12
    
    wall=CreateCube()
    walltex=LoadTexture("stone19.jpg")
    EntityTexture wall,walltex
    EntityColor wall,110,110,110 ; a bit darker please
    ScaleEntity wall,7,6,7
    TranslateEntity wall,6.9,0,0
    FlipMesh wall 
    
    window=CreateSunbeams("churchwin3.jpg",40,5,5,1.0,-1.0,10.0,1,1)
    ScaleEntity window,1,4,2
    
    EntityParent wall,window
    While Not KeyDown(1)
    	ang#=(ang#+1) Mod 180
    	RotateEntity window,0,ang-180,0
    	RenderWorld()
    	Text 0,0,"Tris Rendered: "+TrisRendered()
    	Flip
    Wend
    End
    
    Function CreateSunbeams(texpath$,transp=40,numsurfx#=5,numsurfy#=5,zoom#=1.0,height#=-1.0,lenght#=3.0,vertical_on=1,horizontal_on=1)
    	
    	tex=LoadTexture(texpath$) 
    	tex2=LoadTexture(texpath$,2) 
    	
    	
    	SetBuffer TextureBuffer(tex2)
    	LockBuffer()
    	For j=0 To TextureHeight(tex2)-1
    		For i=0 To TextureWidth(tex2)-1
    			rgb=ReadPixelFast(i,j) And $FFFFFF
    			r=(rgb And $FF0000) Shr 16
    			g=(rgb And $FF00) Shr 8
    			b=(rgb And $FF)
    			minv=128
    			If r>minv Or g>minv Or b>minv Then
    				a = transp Shl 24
    			Else
    				a=0 
    			EndIf
    			r=r*3
    			g=g*3
    			b=b*3
    			If r>255 Then r=255 
    			If g>255 Then g=255 
    			If b>255 Then b=255 
    			argb=a Or (r Shl 16) Or (g Shl 8) Or b
    			WritePixelFast i,j,argb
    		Next
    	Next
    	UnlockBuffer()
    	SetBuffer BackBuffer()
    	
    	
    	win=CreateQuad()
    	EntityTexture win,tex
    	EntityFX win,1
    	
    	
    	mesh=CreateMesh()
    	surf=CreateSurface(mesh)
    	
    	
    	If vertical_on
    		For i=0 To numsurfx#
    			where#=(((Float(i)-numsurfx)/numsurfx)*2.0)+1.0
    			wherev#=(where#+1.0)/2.0
    			v0=AddVertex(surf,-1.0,-1.0,where#,wherev,1.0 )
    			v1=AddVertex(surf, 1.0*lenght,-1.0+height,where#,wherev,1.0)
    			v2=AddVertex(surf, 1.0*lenght,1.0+height,where#,wherev,0.0)
    			v3=AddVertex(surf,-1,1.0,where#,wherev,0.0 )
    			VertexColor surf,v0, 255,255,255,1
    			VertexColor surf,v1, 0,0,0,0
    			VertexColor surf,v2, 0,0,0,0
    			VertexColor surf,v3, 255,255,255,1
    			AddTriangle(surf,v0,v1,v2)
    			AddTriangle(surf,v2,v3,v0)
    		Next
    	EndIf
    	
    	
    	If horizontal_on
    		For i=0 To numsurfy#
    			where#=(((Float(i)-numsurfy)/numsurfy)*2.0)+1.0
    			wherev#=(where#+1.0)/2.0
    			v0=AddVertex(surf,-1.0,where#,-1,1,-wherev )
    			v1=AddVertex(surf, 1.0*lenght,where#*zoom+height,-1,1,-wherev )
    			v2=AddVertex(surf, 1.0*lenght,where#*zoom+height,1,0,-wherev )
    			v3=AddVertex(surf,-1.0,where#, 1,0,-wherev )
    			VertexColor surf,v0, 255,255,255,1
    			VertexColor surf,v1, 0,0,0,0
    			VertexColor surf,v2, 0,0,0,0
    			VertexColor surf,v3, 255,255,255,1
    			AddTriangle(surf,v0,v1,v2)
    			AddTriangle(surf,v2,v3,v0)
    		Next
    	EndIf
    	
    	UpdateNormals mesh
    	EntityFX mesh,16 Or 1 Or 2
    	EntityTexture mesh,tex2
     ;EntityBlend mesh,3
    	TranslateEntity mesh,1,0,0
    	EntityParent mesh,win
    	Return win
    End Function
    
    Function CreateQuad()
    	
    	mesh=CreateMesh()
    	surf=CreateSurface(mesh)
    	v0=AddVertex(surf,0, -1.0, -1.0, 0,1 )
    	v1=AddVertex(surf,0, 1.0, -1.0, 0,0 )
    	v2=AddVertex(surf,0, 1.0, 1.0, 1,0 )
    	v3=AddVertex(surf,0, -1.0, 1.0, 1,1 )
    	AddTriangle(surf,v0,v1,v2)
    	AddTriangle(surf,v2,v3,v0)
    	UpdateNormals mesh
    	Return mesh
    End Function
    Una imagen para compartir -windows..jpg

    Aca va el dodigo
    "No son ni estrellas ni ídolos, son solo gente común que quiere hacer historia"

  6. #6
    Expulsado
    Fecha de ingreso
    Dec 2010
    Ubicación
    En matrix
    Mensajes
    1,681

    Re: Una imagen para compartir.

    oleee, mil gracias. Ahora me pongo a estudiarlo. Gracias por todos los códigos de los que aprendo Blitz3D,

  7. #7
    Senior Member Avatar de Yue
    Fecha de ingreso
    May 2008
    Ubicación
    Bogotá
    Mensajes
    634

    Thumbs up Re: Una imagen para compartir.

    Oye, dime si esto funciona correctamente.

    http://www.mediafire.com/?uaqcbnek2cs8059

    Tecla escape para saltar el la primera scena.

    Un saludo.
    "No son ni estrellas ni ídolos, son solo gente común que quiere hacer historia"

  8. #8
    Expulsado
    Fecha de ingreso
    Dec 2010
    Ubicación
    En matrix
    Mensajes
    1,681

    Re: Una imagen para compartir.

    Si. funciona perfectamente. Mola la presentación con la rueda callendo, esta muy bien, y la animación de la chica también.

  9. #9
    Expulsado
    Fecha de ingreso
    Dec 2010
    Ubicación
    En matrix
    Mensajes
    1,681

    Re: Una imagen para compartir.

    Aun no entendí del todo como hacer el efecto de la luz, se que es con el readpixelfast (algo parecido al efecto blur) pero no se como aplica la textura para que tome esa forma....yo la luz la hacia con un sprite, pero así queda bastante mejor.

  10. #10
    Senior Member Avatar de Yue
    Fecha de ingreso
    May 2008
    Ubicación
    Bogotá
    Mensajes
    634

    Re: Una imagen para compartir.

    Bueno, por ahora no trates de entender la cuestión usa esa función para crear un quad al cual le asignas una textura, y modificas los parámetros para adaptarlos, como transparencia, ángulo de los rayos de luz etc.


    Oye me ayudas con mi pequeño proyecto XD.


    Bueno se acabo el tiempo de nuevo en esto. =(
    "No son ni estrellas ni ídolos, son solo gente común que quiere hacer historia"

  11. #11
    Expulsado
    Fecha de ingreso
    Dec 2010
    Ubicación
    En matrix
    Mensajes
    1,681

    Re: Una imagen para compartir.

    Ya, tienes razón, pero me gusta entender por qué si no, no puedo adaptar los códigos a mi antojo...pero bueno.

    El proyecto del coche rojo que vi en tu web? Si quieres lo testeo o no se en que quieres que te ayude...pero si puedo lo haré.

  12. #12
    Senior Member Avatar de Yue
    Fecha de ingreso
    May 2008
    Ubicación
    Bogotá
    Mensajes
    634

    Re: Una imagen para compartir.

    Bueno, mira una función quad crea un sprite, donde se pega la textura.

    ya la función principal, tiene como objetivos establecer los pixeles claros de la textura, por ejemplo si pones una textura color negro la cosa no va. Así que la textura en las partes claras es la que permite por decirlo de esa manera tirar los pixeles, con los cuales mediante programación se crea un mesh, que es el que hace los rayos de luz.


    Bien, ahora lo de la ayuda es para el testeo de lo que trato de hacer con el que probastes, ya que la idea es hacer al menos un nivel jugable.

    Bueno, escribir desde un movil te me saca apoyas.

    Un saludo.
    "No son ni estrellas ni ídolos, son solo gente común que quiere hacer historia"

  13. #13
    Expulsado
    Fecha de ingreso
    Dec 2010
    Ubicación
    En matrix
    Mensajes
    1,681

    Re: Una imagen para compartir.

    Gracias Blitz3D, pero ya he entendido el código, . Bueno cuando tengas el nivel lo testeare sin problema.

  14. #14
    Senior Member Avatar de xarpo_
    Fecha de ingreso
    Jan 2009
    Ubicación
    Barcelona
    Mensajes
    155

    Re: Una imagen para compartir.

    Blitz3D, la verdad que te admiro, es increíble lo con consigues hacer con Blitz.
    Eres un genio.

Temas similares

  1. algo para compartir
    Por mluke en el foro Trabajos Finalizados
    Respuestas: 46
    Último mensaje: 03-03-2012, 03:45
  2. Para aprender y compartir info los que usemos UDK
    Por ofuscado en el foro Videojuegos
    Respuestas: 4
    Último mensaje: 22-08-2011, 21:47
  3. Blog interesante para compartir
    Por bethoven2009 en el foro Modelado
    Respuestas: 2
    Último mensaje: 28-10-2008, 21:16
  4. es de fiar el sistema para compartir fotos ringo
    Por Gabriel Herrera en el foro Todo menos Infografía
    Respuestas: 1
    Último mensaje: 17-05-2006, 03:13
  5. Nuevo sitio para subir y compartir tus animaciones
    Por Caronte en el foro Todo menos Infografía
    Respuestas: 1
    Último mensaje: 28-05-2005, 01:22

Actualmente estos son sus permisos de publicación en el foro.

  • -No puedes crear nuevos temas al no estar registrado o no haber iniciado sesión en el foro.
  • -No puedes responder temas al no estar registrado o no haber iniciado sesión en el foro.
  • -No puedes subir archivos adjuntos al no estar registrado o no haber iniciado sesión en el foro.
  • -No puedes editar tus mensajes al no estar registrado o no haber iniciado sesión en el foro.
  •